!---------------------------------------------------
! Scene 3: Forest
!---------------------------------------------------   

Object bosdeur
  with found_in tuin,
       door_dir e_to,
       door_to bos_1,
       react_before [;
         Climb, Go, GoIn, Enter: if (noun == self || noun == e_obj || noun == bos_1) {
	     if(TuinNaarBos() == true) return true;
	   };
	 
       ],
   has door scenery open;   
   
  
Object bos_1 "Walking through the forest"
  with 
       description "You make your way through the dim and gloomy forest, hardly able to recognise the snow-covered path in this darkness. Howls penetrate the midnight air: wolves, nearby. Game scarce in these harsh winter months, so the wolves are hungry, bold, and a danger even to men. This coniferous forest is dim and gloomy even on the sunniest days, and in the dead of this winter night it is pitch dark. A path, hardly recognisable as such, leads from the village in the west to the castle in the east. The howls of a pack of wolves rise from nearby. In this season game is scarce, and the wolves are hungry, bold and dangerous even to men.",
       e_to bos_2,
       w_to "Going back to the village is a tempting prospect--tempting, but cowardly. The die is cast; Maartje must be freed.",
       u_to "Even in the best light and without snow it is not easy to climb these large pines, but in the current circumstances it is impossible.",
       d_to "You don't have time for playing in the snow.",
       cant_go "Just setting off across the woods is not going to get you anywhere.",
       before [;
         Listen: <<Examine bos_1_wolven>>;
       ], 
   has light;
   
   Object bomen "trees"
    class Prop,
     with name 'tree' 'trees' 'coniferous' 'pine' 'pines' 'forest' 'wood' 'branch' 'branches' 'woods' 'giants',
          found_in bos_1 bos_2 bos_3,
          description "High above you tower the giants of the forest. These are pines, dozens of years old, their branches heavy under the load of the snow. As you walk, you occasionally glimpse the moon through the trees.",
          before [;
	    Climb, Enter, GoIn, Go: 
	      if (wolvin.status ~= 99) {
	         "Even in the best light and without snow it is not easy to climb these large pines, but in the current circumstances it is impossible.";
	      } else {
	         "You are no squirrel!";
	      }	      
	  ],
      has pluralname;
      
   Object bos_1_wolven "wolves" bos_1
    class Prop,
     with name 'wolves' 'pack' 'howls' 'howl' 'howling',
          description "The howling of the wolves comes from nearby, but perhaps you are not their intended prey.",
	  before [;
	    Listen: <<Examine self>>; 
	    Attack: "You would love to, but the wolves are still too far off.";
	  ],	  
      has pluralname animate;
          
   Object bos_pad "path"
    class Prop,
     with name 'path' 'road' 'snow',
          found_in bos_1 bos_2 bos_3,
          description "The path is almost invisible beneath a powdery layer of snow.",
	  before [;
	    Cross: "You are standing on the path.";
	  ],
      has ;
     
Object bos_2 "Walking through the forest"
  with firsttime 0,
       description [;
            if (wolvin.status ~= 99) {
	       print "Here the path is narrow and winding, and hardly recognisable under the snow. Moonlight penetrates the dense foliage only sporadically. Eastwards lies the baron's castle; to the west, your own footprints lead back to the village.^";
	    } else {
	       print "Here the path is narrow and winding, and hardly recognisable under the snow. Moonlight penetrates the dense foliage only sporadically. Eastwards lies the stone house of the hunter; to the west, the tracks of your prey lead to were the humans live.^";
	    }
	    if(self.firsttime == 0) {
	       StartDaemon(wolvin);
	     };
	    self.firsttime = 1;
	    return true;
         ],
       e_to bos_3,
       w_to bos_1,
       d_to "You don't have time for playing in the snow..",
       u_to [;
            if(action == ##go && noun == u_obj) {
               if (wolvin.status ~= 99) {
                 "Even in the best light and without snow it is not easy to climb these large pines, but in the current circumstances it is impossible.";
		}
	       if (wolvin.status == 99){
	          "You are no squirrel!";
		}
	     }
       ],
       cant_go [; if (wolvin.status ~= 99) {"Just setting off across the woods is not going to get you anywhere.";}
	          else "The house of stone lies to the east.";
	       ],
       before [;
         Go:
	  if(noun == w_obj) {
	    if(wolvin.status < 5) {
	      print "Are you sure you wish to flee from the she-wolf?^";
	      if(YesOrNo()) {
	        print "^You make a hasty escape, back to the village, away from the teeth and the eyes of the bloodthirsty monsters of the forest.^^
		Halfway you have to stop, because of side stitches. You breathe heavily, and lean against a tree for a moment to rest. Shame overwhelms you; if you cannot even face a wolf, how could you ever rescue Maartje from the talons of the baron? No--giving up is no option. You must go back.^";
		PlayerTo(bos_1);
		StopDaemon(wolvin);
		wolvin.status = 11;
		remove wolvin; remove jongewolf; 
		return true;
	      } else {
	        "^You remain where you are, determined not to flee.";
	      };
	    };
	    if(wolvin.status == 99) {
	      "The stone man-house lies at the other end of the man-path. That is where you must go.";
	    };
	  };
	  
	  if(noun == e_obj) {
	    if(wolvin.status < 5) {
	      print "Are you sure you want to try to walk past the ferocious she-wolf?^";
	      if(YesOrNo()) {
	        print "^Step by step you inch forward, keeping as close to the trees as possible. The she-wolf growls dangerously, and keeps her eyes fixed on your face.^^~Show no fear!~, you counsel yourself. Dogs can smell fear, and wolves are really just wilder and smarter dogs. Or so you tell yourself.";
		
		VraagToets(0,0,0);
		
		print "You keep your face straight, and slowly, making no fearful movement, steal past the wolf and then a few steps further. Your heart is beating so wildly that you are surprised not to hear your ribs cracking. Backwards, still facing the she-wolf, you keep walking along the path -- calmly -- without running -- as if you hadn't been afraid for a single moment.^^She holds her ground, and watches you until you've vanished from sight. But she does not pursue you.^";
		
		PlayerTo(bos_3);
		StopDaemon(wolvin);
		wolvin.status = 12;
		remove wolvin; remove jongewolf; 
		return true;
	      } else {
	        "^You stand still, transfixed.";
	      };
	    };
	  };	  
       ],
   has light;

   
   Object wolvin bos_2
     with short_name [;
            if(self has animate) {print "she-wolf"; return;}
	    print "dead she-wolf"; return;
          ],
          description [;
              if (self.status <5) 
	          "For a wolf she is large and extraordinarily ferocious, but winter has clearly taken its toll: she is lean and scrawny, and her fur dirty and dull.";

              if (self.status > 4 && self.status ~= 99) 
	          "The body of the she-wolf lies lifelessly in the snow. On her face you believe you see terrible sorrow.";

	      if (self.status == 99)
	          "You are big and strong, and the warm blood of the human flows through your veins.";
	       ],
          name 'she-wolf' 'wolf' 'mother',
          status 0,
	  offered 0,
	  daemon [;
	    if(self.status == 0) 
	            print "^From the trees to the left, a dark shape suddenly jumps forward. It is a she-wolf; she stops a stone's throw away from you, in the middle of the path, fixating you with two eyes that mirror the moon. From her throat comes a fierce growl.^"; give self ~scenery;
	    if(self.status == 1) { 
	            print "^The she-wolf opens her mouth, revealing two rows of sharp teeth. From the woods, a second shape skulks towards her: a young wolf, very lean.^";
		    move jongewolf to bos_2;
		    };
	    if(self.status == 2) 
	            print "^Carefully, the she-wolf takes two steps towards you. In her growling, ferocity mixes with fear.^";
	    if(self.status == 3) 
	            print "^The she-wolf hesitates, weighing attacking you. Than the young wolf whines, piteously, weakly, and his mother finds the courage of desperation. She readies herself for the leap.^";
	    if(self.status == 4) {
	            print "^As suddenly and quickly as a lightning bolt the she-wolf leaps at your throat. You fall over backwards, and she is standing on top of you. Her sharp teeth sink into your throat and you feel, horrified, how your windpipe is torn to pieces, how warm, sweet blood flows over your tongue, how you gasp for breath like a fish on the land, and how the teeth of the starved young wolf tear open your belly, looking for your steaming entrails, before everything turns black.";
		    
		    VraagToets(0,0,0);
		    
		    BecomeWolf();
		    
		    };
	    if(self.status < 4) {self.status++;}
	  ],
	  before [;
	    Attack: 
	       if (self.status < 5 && parent(axe) == player)
	         {
		   print "You grip the axe so tightly that your knuckles turn white. The wolf growls in warning, but with an undertone of panic. You take a step forwards. She takes half a step backwards; every hair in her neck stands upwards. You take another step forwards, and another one, and she leaps at you--but before her teeth can sink into your throat the axe's blade has smashed her ribcage and enters her body. With a soft whine she falls to the ground and lies still.^";
		   
		   StopDaemon(wolvin);
		   
		   if(self.status == 1) {
		     print "^Between the trees, very near, a heart-rending cry penetrates the night. A small, young wolf stares from a safe distance at his mother's corpse.^";
		     move jongewolf to bos_2;
		   }
		   
		   if(self.status > 1) {
		     print "^The young wolf emits a heart-rending cry, then jumps away, between the trees. From a safe distance it stands staring at its mother's corpse, whining pitifully.^";
		    }

		   wolvin.status = 5; give wolvin ~scenery; give wolvin ~animate;
		   return true;
		   
		};
	       
	       if (self.status < 5 && parent(axe) ~= player)
	         {
		   print "With clenched fists, you carefully take a step towards the she-wolf. The wolf growls in warning, but with an undertone of panic. You take a step forwards. She takes half a step backwards; every hair in her neck stands upwards. You take another step forwards, and another one, and she leaps at you--but before her teeth can sink into your throat your fist connects with the side of her head, temporarily averting her attack. You fall over backwards, her weight on top of you, but with a nimble roll you succeed in freeing yourself. Again she tries to reach your throat, but your hands have already found hers and with your greater weight you pin her to the ground. You squeeze, and squeeze, and hit her head against the ground, while she desperately attempts to get loose. Her saliva streams across your hands; her blood starts colouring the snow; her movements become weaker by the moment. The struggle lasts for minutes, but finally she lies still, dead. Fatigued and with your heart pounding, you arise.^";

		   StopDaemon(wolvin);
		   
		   if(self.status == 1) {
		     print "^Between the trees, very near, a heart-rending cry penetrates the night. A small, young wolf stares from a safe distance at his mother's corpse.^";
		     move jongewolf to bos_2;
		   }
		   
		   if(self.status > 1) {
		     print "^The young wolf emits a heart-rending cry, then jumps away, between the trees. From a safe distance it stands staring at his mother's corpse, whining pitifully.^";
		    }
		    		   
                   wolvin.status = 6; give wolvin ~scenery; give wolvin ~animate;
		   return true;
		 };	
		 
	     Touch: 
	         if (self.status < 5) {
		    print "You swallow nervously, but then you reach towards the wolf, speaking sweet words.^^
		    ~Come here, little wolf. Come. Sweet, yes, sweet wolf. Come to me...~^^
		    Hesitatingly the she-wolf approaches, uncertain about your intentions. She smells your hand, then licks it. You lower yourself to your knees, vulnerable, and softly stroke the she-wolf's head. She comes yet nearer, and licks your face. Then you embrace her, putting your arms around her neck, laughing.^^";
		    
		    wolf_touch.select(99);
		    
		    if (self.status == 9) {
		       print "All tension leaves her muscles. Long minutes the two of you sit in that position: you embrace her, she lets her head rest on your shoulder.";
		       if (parent(jongewolf) == bos_2) print " The young wolf too, after some misgivings, snuggles up to you.";
		       print "^^But you cannot forget Maartje and the importance of your quest. You let go of the she-wolf, and arise.^^
		       ~I'm sorry, but I can't do anything for you. I have to go, to save my daughter.~^^
		       The ";
		       if (parent(jongewolf) == bos_2){ 
		          print "two wolves regard you with understanding in their eyes. Then they calmly walk back into the forest, to look for another prey that can save their lives.^";
		        }else{
			  print "wolf regards you with understanding in her eyes. Then she calmly walks back into the forest, where a lean young wolf joins here. Together they leave, in search of another prey that can save their lives.^";
		       };
		       
		       StopDaemon(wolvin);
		       
		       remove wolvin; remove jongewolf;
		     };
		     
		    if (self.status == 10) {
		       if (parent(jongewolf) == bos_2){ 
		          print "The young wolf emits a heart-rending cry when he sees what you have done. In his eyes burns a ferocious hatred, and for a moment it appears as if he wants to attack you, the betrayer. Then his fear is victorious and he runs, still howling with deep sorrow, away into the woods.^";
		        }else{
			  print "From the forest you suddenly hear a heart-rending cry. Between the trees stands a small young wolf, lean and dirty. In his eyes burns a ferocious harted, and for a moment it appears as if he wants to attack you, the betrayer who has killed his mother. Then his fear is victorious and he runs, still howling with deep sorrow, away into the woods.^";
		       };
		     
		       StopDaemon(wolvin);
		       
		       remove jongewolf;
		       
		     };
		    
		    return true;
		 };
		 
	      JumpOver:  
	         if(self.status < 5) {
		    
		    print "This plan is madness; but, so you tell yourself, this whole undertaking is madness anyway. You take a few steps backward, to all appearances as if preparing for flight; then you suddenly jump forward, right at the she-wolf--who recoils from your sudden approach--and just before you reach her you jump...";
		    
		    VraagToets(0,0,0);
		    
		    print "...right over her. You land face-first in the thick layer of snow, but you immediately recover your footing and start running. Behind you an angry howling resounds through the dark forest, and it seems as if you hear something running through the snow, but you don't look back--your entire being is focussed on what is in front of you, and how you can get there as quickly as possible.";
		    
		    VraagToets(0,0,0);
		    
		    print "You have no idea how long you have sustained your sprint, but when you turn around, breathing heavily, the wolf is nowhere to be seen.^";
		        
		    PlayerTo(bos_3);
		    StopDaemon(wolvin);
		    wolvin.status = 13;
		    remove wolvin; remove jongewolf; 
		    return true;
		 
		 }

	      Spreek: 
	          if (self.status < 5) {
		    wolf_spraak.select(1);
		    return true;
		  }
	  ],
	  orders [;
               Eat: if(self.status < 5) {
	              print "You undo the top buttons of your coat and lie down in the show, offering your bare throat to the she-wolf. Suspicious, she slowly walks towards you, but her hunger is greater than her fear. Sharp teeth sink into your throat and you feel, calmly and as if from a distance, how your windpipe is torn to pieces, how warm, sweet blood flows over your tongue, before everything turns black.";
		  
		      VraagToets(0,0,0);
		    
		      BecomeWolf();
		      self.offered = 1;
		      
		      return true;
	            };
	    
	       Unlock, Lock, SwitchOn, SwitchOff, Open, Close, Disrobe, Wear, Wave, ThrowAt, Tie, Fill, Swing, Rub, Squeeze:
	                	    if(self.status == 99){
	                              "That is impossible, without hands.";    
	    	                    };
	       Take:                if(self.status == 99){
	                              "You prefer having your mouth free to bite with";    
	    	                    };
	  ],
	  react_before [;
	       Drop, Give, ThrowAt:
	        if (wolvin.status < 5 && second ~= jongewolf) {  
		  if (noun == dagboek && parent(dagboek) == player) {
		    
		      remove dagboek;
		      remove wolvin;
		      remove jongewolf;
		      
		      print "You take Maartje's diary and throw it to the wolf, hoping to distract her. It lands on the ground next to her, open, the black pages upwards. Immediately, and with terrifying savagery, the she-wolf jumps on the diary and starts tearing out the pages. ";
		      
		      if(wolvin.status == 1) {
		         print "From the brushwood a small, young, very lean wolf regards its mother.^^When she has torn all the pages from the diary and has collected them in her mouth, she walks backwards, her eyes not leaving you for a moment, and joins her young. When she has reached the trees, she turns around and disappears quickly into the woods. The little wolf follows her with the same astounding speed.^";
		       } else {
		         print "The young wolf joins his mother, gathering the torn out pages in his mouth, while his fearful eyes stay fixed on your face. In a few seconds their work is done: with their bounty in their mouths, the wolves turn around and quickly disappear into the woods.^";
		       };
		       
		      StopDaemon(wolvin);
		      
		      move kaft to bos_2;
		      print "^All that remains, lying in the snow, is the diary's cover.^";
		      
		      wolvin.status = 7;
		      return true;       
		    };
		  
		  
	          if (noun == beer && parent(beer) == player) {
	      
		      remove beer;
		      remove wolvin;
		      remove jongewolf;
		      
		      print 
		        "You take Brown. His button eyes implore you to reconsider.^^
			~Sorry Brown,~ you say, and throw him to the she-wolf, hoping to distract her attention.^^
			Before the toy bear has reached the ground, she has caught it in her mouth. ";
		      
		      if(wolvin.status == 1) {
		         print "From the woods a small, very lean wolf walks onto the path, to his mother and her bounty. He starts to pull at Brown's head, which after a few pulls is torn from his body with a ripping sound. Then mother and child disappear into the woods, warily keeping their eyes on you, each of them holding a part of Maartje's loyal friend between their teeth.^";
		       } else {
		         print "The young wolf walks towards his mother and starts pulling at Brown's head. After several pulls, it is torn from his body with a ripping sound. Then mother and child disappear into the woods, warily keeping their eyes on you, each of them holding a part of Maartje's loyal friend between their teeth.^";
		       };
		       
		      StopDaemon(wolvin);
		      
		      wolvin.status = 8;
		      return true;       
		    };
		   };
		  
		   
	        Take: if(self.status < 5) "The she-wolf doesn't look like she'll take kindly to you trying to pick her up.";
		      if(self hasnt animate) "You have little inclination to walk around with the dead body of a wolf.";
	  ],
	  life [;
	     Kiss: if (self.status < 5) {<<Touch self>>;};
	     Show: if (self.status < 4) {
	              if(noun == beer) "Saliva starts dripping from the she-wolf's mouth when she sees the tender toy bear.";
		      if(noun == dagboek) "The she-wolf eyes the diary hungrily.";
		      
		   }
	  ],
      has scenery female animate;
   
   Object jongewolf "young wolf"
     with pname '.p' 'young' 'wolf' '.p' 'young' '.p' 'child' '.p' 'son',
          short_name [;
            if(self has animate && wolvin.status ~= 99) {print "young wolf"; return;}
	    if(self has animate && wolvin.status == 99) {print "your young"; return;}
	    print "dead young wolf"; return;
          ],
          description 
               "Like its mother, the young wolf has a dark grey pelt, turned dirty and lustreless through hardships. He is so lean that you can count all his ribs. If his mother doesn't find a prey soon, he will not survive the winter.",
	  before [;
	    Take: if(wolvin.status == 5 || wolvin.status == 6) {
	       "The young wolf shrinks back at your approach.";
	    } else if (wolvin.status < 5) {
	       "You'll have to deal with the mother before you can try to pick up the young wolf--although it is improbable that he will let you.";
	    } else if (wolvin.status == 99) {
	       "No matter how strongly it goes against your instincts, you know that it is safer for you to leave your young than take him with you to the man-house.";
	    };
	    
	    Touch: if(wolvin.status == 5 || wolvin.status == 6) {
	       "The young wolf shrinks back at your approach.";
	    } else if (wolvin.status < 5) {
	       "You'll have to deal with the mother before you can try to touch the young wolf--although it is improbable that he will let you.";
	    } else if (wolvin.status == 99) {
	       "You lick your young and playfully bite him in the scruff of his neck. He looks at you with large eyes full of trust and growls contentedly before he starts devouring the prey again.";
	    };
	    
	    Push, Pull: if(wolvin.status == 5 || wolvin.status == 6) {
	       "The young wolf shrinks back at your approach.";
	    } else if (wolvin.status < 5) {
	       "The she-wolf certainly won't let you touch her child.";
	    } else if (wolvin.status == 99) {
	       "Why would you want to push or pull your child?";
	    };
	    
	    Attack: if(wolvin.status == 5 || wolvin.status == 6) {
	       attack_wolfje.select(1);
	       return true;
	    } else if (wolvin.status < 5) {
	       "His mother will certainly try to defend him.";
	    } else if (wolvin.status == 99) {
	       "You do not attack your own child.";
	    };
	    
	    Spreek: if(wolvin.status == 5 || wolvin.status == 6) {
	       spreek_wolfje.select(1);
	       return true;
	    } else if (wolvin.status < 5) {
	       "His mother holds your attention at the moment.";
	    } else if (wolvin.status == 99) {
	       "You lovingly growl at your child. He growls back, contentedly.";
	    };
	  ],
	  react_before [;
	    ThrowAt, Give: if (wolvin.status < 5) {
	       if(noun == dagboek && second == self) {<<throwat dagboek wolvin>>;}
	       if(noun == beer && second == self) {<<throwat beer wolvin>>;}
	       return false;
	    }
	  ],
	  life [;
	    Kiss: if(wolvin.status == 5 || wolvin.status == 6) {
	       "The young wolf shrinks back at your approach.";
	    } else if (wolvin.status < 5) {
	       "The she-wolf won't let you touch her child.";
	    } else if (wolvin.status == 99) {
	       "Wolves don't kiss.";
	    };
	  ],
      has animate male;
      
   Object dode_ik "half-devoured corpse"
     with name 'dead' 'body' 'man' 'human' 'corpse' 'me' 'half-devoured',
          description 
              "A half-devoured human corpse lies in the snow. His blood reddens the snow around him.",
      has ;
      
   Object kaft "cover of Maartje's diary"
     with name 'cover' 'diary',
          description "A cover, thick cardboard enveloped by fake red leather, is all that remains of Maartje's diary.",
	  before [;
	    Burn: "The fake leather doesn't burn.";
	  ],
      has ;

      
      
      
      
      
            
Object bos_3 "On a path in the forest"
  with description 
             [; 
	       if (wolvin.status ~= 99) {
	          "From this part of the winding path, you can see the baron's castle rising in the east. The silhouette with the three leaning towers is outlined against the starry sky. A trail of footprints--yours--indicate the path to the west. Here, so close to the baron's domain, even the wolves are silent.";
	       } else {
	          "From this part of the winding path, you can see the stone house of the evil human rising in the east. The silhouette with the three leaning towers is outlined against the starry sky. A trail of paw prints--yours--indicates the path to the west. It is silent here; even the howling of your pack has faded.";
	       }
	     ],
       e_to ophaalbrug,
       w_to bos_2,
       d_to "You don't have time for playing in the snow.",
       cant_go 
               [; if (wolvin.status ~= 99) {"Just setting off across the woods is not going to get you anywhere.";}
	          else "The house of stone lies in the east.";
	       ],
       before [;
         Go: if(noun == w_obj) {
	        if(wolvin.status == 12) {
		   "Perhaps the she-wolf won't let you go as easily this time - for the time being, it is better not to return.";
		 };
	        if(wolvin.status == 13) {
		   "After your quick sprint, you feel little inclination to go back to the dangerous wolf.";
		 };
		if(wolvin.status == 15) {
		   "Who knows how long the she-wolf will remain calm? You decide to be safe rather than sorry, and not to return until you have to.";
		 };
		if(wolvin.status == 25 || wolvin.status == 26) {
		   "It is better to let the young wolf eat in peace. He has suffered enough for tonight.";
		 };
		
	     }
	  Listen: "It is completely silent here--unnaturally silent."; 
       ],
   has light;
   
   
   Object kasteel_in_bos "castle" bos_3
    class Prop,
     with name 'castle' 'keep' 'house' 'stone' 'tower' 'towers',
          description [;
	    if (wolvin.status == 99) {
	      "The stone house of the evil human is big and hard. You have never been inside, and do not know what dangers may have made their home there.";
	     }
	    else 
	      "The baron's castle is a curious building: it has three large towers, of which the outer two lean outwards. The middle tower, thicker and higher than the others, always seems to lean towards the direction from which you are looking. As far as you can see, no light burns in the castle.";
	   ],
      has ;

      
   Object afdrukken "footprints" bos_3
    class Prop,
     with name 'pawprints' 'footprints' 'prints' 'paw' 'foot' 'trail' 'tracks',
          description "They are exactly where you have stepped, from the west to this point.",
      has ;
   
  
   
   
      
   
   
Object wolf_touch
 class Character,
  with quip [a b;
             switch (a) {
               993: qtype = MainMenu;
	            qqon  = true;
                    killz = true;
                    killq = true;
	       994: return Qlist(b, 2,
                                    1,
                                    2);
	     
               11: "Calm the she-wolf completely.";
               12: print "^~All right, relax. Neither of us wants to fight, do we?~, you whisper in her ear.^^";
	           wolvin.status = 9; return true;
               13:  qqon  = true;
                    killz = true;
                    killq = true;
             
               21: "Break her neck";
               22: 
	           print "^~All right, relax,~ you whisper in the wolf's ear. Then, suddenly, you apply all the force you can muster, and break her neck with a sharp jerk. She emits a soft howl, but then lies still and limp in your arms.^^";
		   wolvin.status = 10;  give wolvin ~scenery; give wolvin ~animate; return true;
	       
               23:  qqon  = true;
                    killz = true;
                    killq = true;
	     
	     }
             rfalse;
 
       ],
   has concealed;   
         

Object wolf_spraak
 class Character,
  with quip [a b;
             switch (a) {
               13: qtype = MainMenu;
	            qqon  = true;
                    killz = true;
                    killq = true;
	       14: return Qlist(b, 3,
                                    2,
                                    3,
				    4);
	     
             
               21: "Growl angrily and threateningly.";
               22: 
	           print "^The she-wolf raises every hair in her neck, and growls back fiercely. Her muscles are tensed, ready to leap at you.^^";
               23: killz = true;
                   killq = true;
	       24: return Qlist(b, 3,
	                           5,
				   6,
				   7);


               31: "Growl softly and calmingly.";
               32: 
	           print "^For a moment the she-wolf seems surprised that she can communicate with you. Then her muscles relax a bit, because it is evident that you do not mean her harm.^^";
               33: killz = true;
                   killq = true;
	       34: return Qlist(b, 3,
	                           8,
				   9,
				   4);

   
               41: "Howl, sorrowfully, to the moon.";
               42: 
	           print "^You lift your head and howl and howl, and it sounds exactly like the lament of a wolf. You never knew that so much pain and sorrow where hidden in your heart; now, as clear as crystal, the tones of your grief sound through the night. After several moments the wolf follows your example, and together you howl a heart-breaking duet.";
		   VraagToets(0,0,0);
		   print "After an eternity, you fall silent. The she-wolf regards you for a moment, then nods her head a single time, and disappears into the snow-covered woods.";
		   if(wolvin.status>1) print " Her young follows her.";
		   print "^";
		   StopDaemon(wolvin);
		   wolvin.status = 14;
		   remove wolvin; remove jongewolf; 
		   return true;
               43: killz = true;
                   killq = true;		    

               51: "Attack her.";
               52: <<attack wolvin>>; 
               53: killz = true;
                   killq = true;

               61: "Growl again, fiercely.";
               62: if(wolvin.status == 1) {
	               print "^The she-wolf opens her mouth, revealing two rows of sharp teeth. From the woods a second shape slinks towards her: a young wolf, very lean.";
		       VraagToets(0,0,0);
	           }
	           wolvin.status = 4; return true;
               63: killz = true;
                   killq = true;

               71: "Offer her your throat.";
               72: action = ##Eat;
	           actor = wolvin;
                   noun = player;
                   return wolvin.orders();           
               73: killz = true;
                   killq = true;

               81: "Walk past her.";
               82: 
	           print "Now that she has been calmed, it is easy to walk past the wolf. She stares after you, but she shows no intention of following you.";
		   VraagToets(0,0,0);
		   print "When you can no longer see her in the darkness, you hear her howling break the silence of the night. She sounds lonely.^^
		   You walk on, in the direction of the baron's castle.^";
		   PlayerTo(bos_3);
		   StopDaemon(wolvin);
		   wolvin.status = 15;
		   remove wolvin; remove jongewolf; 
		   return true;
               83: killz = true;
                   killq = true;

               91: "Stroke her.";
               92: <<touch wolvin>>;
               93: killz = true;
                   killq = true;

        
	     }
             rfalse;
 
       ],
   has concealed;      
      
   
Object attack_wolfje
 class Character,
  with quip [a b;
             switch (a) {
               13: qtype = MainMenu;
	            qqon  = true;
                    killz = true;
                    killq = true;
	       14: return Qlist(b, 3,
                                   2,
                                   3,
				   4);
	     
               21: "Kill him, because a world without wolves is a better place.";
               22: if (parent(axe) == player) {
	             print "You grin, run at the young wolf, and before he has been able to react you split his body with a single blow of your axe. Another wolf less. The blood spurts in thick streams across the ground, while his warm entrails slowly sink into the melting snow.^";
	           } else {
		     print "You grin, and with a leap you jump right on top of the little wolf. Compared to his mother he is easy prey: with your strong arms you break his spine without too much effort. The small body lies still in the snow. Another wolf less.^";
		   }
	       
	           give jongewolf ~animate; give jongewolf ~male; return true;
               23:  qqon  = true;
                    killz = true;
                    killq = true;
             
               31: "Kill him, to spare him the slow suffering of starvation.";
               32: 
	           print "~Come here, little wolf,~ you softly say, while you let yourself sink to your knees. With sweet words and calming gestures you are able to approach the small animal, still in shock because his mother died, very closely.";
		   
		   VraagToets(0,0,0);
		   
		   print "~I am very sorry, but this is for the best,~ you whisper. With a quick movement you grab his head and break his neck. The small body goes limp immediately; from his mouth escapes a momentary whimper--then his is silent and the light in his eyes goes out.^^
		   Tears roll down over your cheeks.^";
	               
	           give jongewolf ~animate; give jongewolf ~male; return true;
               33:  qqon  = true;
                    killz = true;
                    killq = true;
		    
               41: "Scare him away.";
               42: if (parent(axe) == player) {
	             print "Screaming loudly, waving your axe, you run at the little animal, which runs away as fast as it can. It soon disappears into the woods.^";
	           } else {
		     print "Screaming loudly, waving your arms, you run at the little animal, which runs away as fast as it can. It soon disappears into the woods.^";
		   }
	           
		   remove jongewolf; return true;
               43:  qqon  = true;
                    killz = true;
                    killq = true;
	     
	     }
             rfalse;
 
       ],
   has concealed;  
   
   
Object spreek_wolfje
 class Character,
  with quip [a b;
             switch (a) {
               13: qtype = MainMenu;
	            qqon  = true;
                    killz = true;
                    killq = true;
	       14: return Qlist(b, 3,
                                   2,
                                   3,
				   4);
	     
               21: "~Go away, dumb beast! Shoo!~";
               22: 
	           print "Screaming loudly, waving your arms, you run at the little animal, which runs away as fast as it can. It soon disappears into the woods.^";
           
		   remove jongewolf; return true;
	           
               23:  qqon  = true;
                    killz = true;
                    killq = true;
             
               31: "~I... I... I am sorry that I killed your mother.~";
               32: 
	           print "The young wolf looks at you, sad and uncomprehending.^^";
	       
               33:  qqon  = true;
                    killz = true;
                    killq = true;
	       34: return Qlist(b, 4,
                                   5,
                                   6,
				   7,
				   4);

   
               41: "Howl a lament for his lost mother.";
               42: 
	           print "^You lift your head and howl and howl, and it sounds exactly like the lament of a wolf. You never knew that so much pain and sorrow where hidden in your heart; now, as clear as crystal, the tones of your grief sound through the night. After several moments the young wolf follows your example, and together you lament his mother's death.";
		   VraagToets(0,0,0);
		   print "After an eternity you fall silent. The little wolf looks at you--in his eyes you see only sorrow. Then he glances at the lifeless body of his mother for the last time, turns around, and disappears forever into the snow-covered forest.^";
		   
		   remove jongewolf; return true;
	       
               43:  qqon  = true;
                    killz = true;
                    killq = true;     

               51: 
	           "~You can't survive alone. It is for the best if I spare you the slow death of starvation.~";
               52: 
	           print "~Come here, little wolf,~ you softly say, while you let yourself sink to your knees. With sweet words and calming gestures you are able to approach the small animal, still in shock because his mother died, very closely.";
		   
		   VraagToets(0,0,0);
		   
		   print "~I am very sorry, but this is for the best,~ you whisper. With a quick movement you grab his head and break his neck. The small body goes limp immediately; from his mouth escapes a momentary whimper--then his is silent and the light in his eyes goes out.^^
		   Tears roll down over your cheeks.^";
	               
	           give jongewolf ~animate; give jongewolf ~male; return true;
	       
               53:  qqon  = true;
                    killz = true;
                    killq = true;    
		    
               61: "~Everything will turn out all right, some day. You will overcome this loss and learn to cope for yourself.~";
               62: 
	           print "The eyes of the young wolf dwell for a while on the soulless corpse of his mother. He lifts his little head an howls once again, a sharp note of pain and desperation. Then he turns around and walks alone and without looking back into the vastness of the forest.^";
		   
		   remove jongewolf; return true;
	       
               63:  qqon  = true;
                    killz = true;
                    killq = true;    
		    
               71: 
	            "~In the future you must go your own way, but now I can try to help you. Let your mother do you a last favour: no matter how grisly it is, you must eat her body in order to survive.~";
               72: 
	           print "The small wolf looks at you with comprehending eyes, but doesn't dare to approach as long as you stand next to the body. Calmly you walk away, towards the baron's castle. Only when you have walked so far that he is hardly visible in the darkness of the night, the young wolf leaves the trees and starts eating his mother's corpse--with revulsion that quickly turns to enthusiasm.^^
		   
		   Fascinated, and with a mixture of horror and pity, you observe the scene for a while. Then you pick up speed again: you still have to free your daughter.^";
		   
		   wolvin.status = wolvin.status + 20;
		   remove jongewolf;
		   PlayerTo(bos_3);
		   return true;
	       
               73:  qqon  = true;
                    killz = true;
                    killq = true;    
	     }
             rfalse;
 
       ],
   has concealed;